*Skåring av norsk versjon av RAND-12 (SF-12 versjon 1) i SPSS*

*Fagsenter for pasientrapporterte data (2022). https://www.kvalitetsregistre.no/fagsenter-pasientrapporterte-data*

*Syntaksen er grundig testa, men brukar har det fulle ansvar for at skåringa er riktig* 

*Kjelde for metode: Andersen JR et al (2022). Correlated physical and mental health composite scores for the RAND-36 and RAND-12 health surveys: can we keep them simple?. Health and Quality of Life Outcomes, 20(1), 1-8.*
 
*Variabelnamna i SPSS-fila med RAND-12 data må ha same namn som i denne syntaksen*

*NB! variabelnamna vert brukt i utrekninga av skår (sjå punkt #6 til slutt i skriptet) må IKKJE brukast som variabelnamn i fila elles då desse kan bli overskrivne eller sletta når ein køyrer syntaksen*  

*Dette syntaksen gir skår for PCS12 og MCS12 når det er svart på minimum 1 spørsmål på kvar subskår*


*Syntaks*

* 1.Bevare rådata slik at dei kan nyttast til kontroll*
 
COMPUTE GH1 = RAND36_1. 
COMPUTE PF2 = RAND36_3b. 
COMPUTE PF4 = RAND36_3d. 
COMPUTE RP2 = RAND36_4b. 
COMPUTE RP3 = RAND36_4c. 
COMPUTE RE2 = RAND36_5b. 
COMPUTE RE3 = RAND36_5c. 
COMPUTE BP2 = RAND36_8. 
COMPUTE MH3 = RAND36_9d. 
COMPUTE VT2 = RAND36_9e. 
COMPUTE MH4 = RAND36_9f. 
COMPUTE SF2 = RAND36_10.


* 2. Fjerne verdiar som er utanfor mogelege alterantiv*

*Fjerne verdiar utanfor 1-2*

RECODE
 RP2 RP3 RE2 RE3
(1=1) (2=2) (ELSE=SYSMIS) .


* Fjerner verdiar utanfor 1-3*

RECODE
 PF2 PF4
(1=1) (2=2) (3=3) (ELSE=SYSMIS) .


* Fjerne verdiar utanfor 1-5*

RECODE
  GH1 BP2 SF2
(1=1) (2=2) (3=3) (4=4) (5=5) (ELSE=SYSMIS) .


* Fjerne verdiar utanfor 1-6*

RECODE
  MH3 VT2 MH4
(1=1) (2=2) (3=3) (4=4) (5=5) (6=6) (ELSE=SYSMIS) .



*3  Kode om til 0-100 skår slik at høgare skår betyr betre helse på alle 12 items.*

RECODE RP2 RP3 RE2 RE3 (1=0) (2=100).
RECODE PF2 PF4 (1=0) (2=50) (3=100).   
RECODE GH1 BP2 (1=100) (2=75) (3=50) (4=25) (5=0).
RECODE SF2 (1=0) (2=25) (3=50) (4=75) (5=100).
RECODE MH3 VT2 (1=100) (2=80) (3=60) (4=40) (5=20) (6=0).
RECODE MH4 (1=0) (2=20) (3=40) (4=60) (5=80) (6=100).



*4  Lage 8 domeneskår.* 
 
COMPUTE PF = MEAN(PF2,PF4). 
COMPUTE RP = MEAN(RP2,RP3). 
COMPUTE BP = MEAN(BP2). 
COMPUTE GH = MEAN(GH1). 
COMPUTE VT = MEAN(VT2). 
COMPUTE SF = MEAN(SF2). 
COMPUTE RE = MEAN(RE2,RE3). 
COMPUTE MH = MEAN(MH3,MH4).  
 

*5. Lage fysisk sumskår (PCS12) og mental sumskår (MCS12) (0-100 skår).* 
 
COMPUTE PCS12=MEAN.4(PF,RP,BP,GH).
EXECUTE.

COMPUTE MCS12=MEAN.4(VT,SF,RE,MH).
EXECUTE.


* 6. OBS! slettar alle hjelpevariablane. Utelat denne kommandoen om du vil sjå heile utrekninga*

DELETE VARIABLES GH1 PF2 PF4 RP2 RP3 RE2 RE3 BP2 MH3 VT2 MH4 SF2 .
EXECUTE.